サンプルのタグを付けられた記事一覧

前回に引き続き、「ZigZag」インジケータを利用します。

この「ZigZag」インジケータをつかって、別のインジケータを作ってみましょう。

「簡単インジケータ作成テンプレート」を使ったサンプルを作ってみます。

テンプレートを適当なファイル名にコピーして、

インストールパス\MetaTrader\experts\indicators

に入れてください。

コピーした、テンプレートのinit()を以下のように修正してください。

int init()

{

//—- indicators

SetIndexStyle(0,DRAW_ARROW, EMPTY, 4);

SetIndexArrow(0,159);

SetIndexBuffer(0,ExtMapBuffer1);

SetIndexStyle(1,DRAW_ARROW, EMPTY, 2);

SetIndexBuffer(1,ExtMapBuffer2);

SetIndexStyle(2,DRAW_ARROW, EMPTY, 2);

SetIndexBuffer(2,ExtMapBuffer3);

//—-

return(0);

}

次は、DataSet()を以下のように修正してください。

void DataSet(int i)

{

ExtMapBuffer1[i]=iCustom(NULL, 0, “ZigZag”,12,5,3,0,i);

ExtMapBuffer2[i]=iCustom(NULL, 0, “ZigZag”,12,5,3,1,i);

ExtMapBuffer3[i]=iCustom(NULL, 0, “ZigZag”,12,5,3,2,i);

}

これで終了です。

今回注目する点は、

iCustom(NULL, 0, “ZigZag”,12,5,3,2,i);

インターフェース仕様は、

double iCustom( string symbol, int timeframe, string name, …, int mode, int shift)

で、symbolにNULLを入れることで、今利用している通貨ペアを使用します。

timeframeに0を入れることで、今利用している通貨ペアの時間軸を使います。

nameは、利用したいインジケータ名「ZigZag」。

ファイル名の拡張子をのぞいた名前を使います。

問題は、次の…。

ここは、利用元のインジケータのパラメータを入れます。

「ZigZag」は、3つパラメータがあるので、３つ。

12,5,3

を指定しています。

利用元のインジケータのパラメータが0なら0、20なら20。

引数が可変になるので、分かりにくいところです。

modeは、何番目のバッファから取得するか。

shiftは、何番目の足の情報を取得するかです。

パラメータ設定部分が、わかりにくいので注意してくださいね。

コンパイルして、動かすと元々線が出ていた場所は、赤丸。

バッファ１が青い×。

バッファ2が緑の×。

が表示されるはずです。

この方法は、いろいろなインジケータから情報を取得できるので、おもしろいことができると思います。

前回に引き続き、「簡単インジケータ作成テンプレート」を使ったサンプルを作ってみます。

今回もボリンジャーバンドを利用します。

ボリンジャーバンドにタッチしたら、売ったり買ったりすることが結構あると思います。

でも、本当にタッチしているかどうか分かりにくいですよね。

なので、タッチしているときだけ色を変えるようなインジケータを作ってみます。

まだ、テンプレートをダウンロードしていない人は、「簡単インジケータ作成テンプレート」からダウンロードしてください。

indicator_temp.mq4をコピーして、適当な名前にしてください。

例として、BB_I.mq4とします。

このファイルは、

インストールパス\MetaTrader\experts\indicators

に入れてくださいね。

いつものようにメタトレーダーを起動して、メタエディターを開いてください。

そこで、先ほど作ったBB_I.mq4を開きます。

変更する場所は、一番下の関数

DataSetだけです。

以下のように修正してみてください。

void DataSet(int i)

{

   double dBBUp = iBands(NULL,0,Param1,2,0,PRICE_CLOSE,MODE_UPPER,i);

   double dBBDown = iBands(NULL,0,Param1,2,0,PRICE_CLOSE,MODE_LOWER,i);

   if(dBBUp < High[i])

   {

      ExtMapBuffer1[i]=dBBUp;

   }

   else

   {

      ExtMapBuffer2[i]=dBBUp;

   }

   if(dBBDown > Low[i])

   {

      ExtMapBuffer3[i]=dBBDown;

   }

   else

   {

      ExtMapBuffer4[i]=dBBDown;

   }

//   ExtMapBuffer5[i]=iMA(NULL,0,14,0,MODE_SMA,PRICE_WEIGHTED,i);

//   ExtMapBuffer6[i]=iMA(NULL,0,14,0,MODE_EMA,PRICE_WEIGHTED,i);

//   ExtMapBuffer7[i]=iMA(NULL,0,14,0,MODE_SMMA,PRICE_WEIGHTED,i);

//   ExtMapBuffer8[i]=iMA(NULL,0,14,0,MODE_LWMA,PRICE_WEIGHTED,i);

}

今回は、上下2色使うので、上側にExtMapBuffer1、ExtMapBuffer2

下側に、ExtMapBuffer3、ExtMapBuffer4を割り当てます。

ボリンジャーバンドの上側のラインより高値が高い場合に、ExtMapBuffer1に値をセット。

低い場合に、ExtMapBuffer2にセットします。

下側も同様にセットしています。

ボリンジャーバンドで利用する足の数を変えられるように、Param1を使いました。

コンパイルして、描画させたいグラフにドロップしてみてください。

Param1は0になっているので、21とか適当な値にしてください。

線の太さや色もパラメータで設定できますので、いじってみてくださいね。

表示させた結果、ちゃんと色が変わっているのが分かりましたか？

でも、なんか線が飛んでいませんか？

データを入れていないところは、デフォルトでEMPTY_VALUEという描画しない値が、入っています。

ちょうど、書き始めに値が入っていないため抜けているんですね。

というわけで、ちょっと気持ち悪いので、たりない情報を別のバッファからもらうように修正してみます。

void DataSet(int i)

{

   double dBBUp = iBands(NULL,0,Param1,2,0,PRICE_CLOSE,MODE_UPPER,i);

   double dBBDown = iBands(NULL,0,Param1,2,0,PRICE_CLOSE,MODE_LOWER,i);

   if(dBBUp < High[i])

   {

      ExtMapBuffer1[i]=dBBUp;

      if(ExtMapBuffer1[i+1] == EMPTY_VALUE)ExtMapBuffer1[i+1] = ExtMapBuffer2[i+1];

   }

   else

   {

      ExtMapBuffer2[i]=dBBUp;

      if(ExtMapBuffer2[i+1] == EMPTY_VALUE)ExtMapBuffer2[i+1] = ExtMapBuffer1[i+1];

   }

   if(dBBDown > Low[i])

   {

      ExtMapBuffer3[i]=dBBDown;

      if(ExtMapBuffer3[i+1] == EMPTY_VALUE)ExtMapBuffer3[i+1] = ExtMapBuffer4[i+1];

   }

   else

   {

      ExtMapBuffer4[i]=dBBDown;

      if(ExtMapBuffer4[i+1] == EMPTY_VALUE)ExtMapBuffer4[i+1] = ExtMapBuffer3[i+1];

   }

//   ExtMapBuffer5[i]=iMA(NULL,0,14,0,MODE_SMA,PRICE_WEIGHTED,i);

//   ExtMapBuffer6[i]=iMA(NULL,0,14,0,MODE_EMA,PRICE_WEIGHTED,i);

//   ExtMapBuffer7[i]=iMA(NULL,0,14,0,MODE_SMMA,PRICE_WEIGHTED,i);

//   ExtMapBuffer8[i]=iMA(NULL,0,14,0,MODE_LWMA,PRICE_WEIGHTED,i);

}

これで、試してみてください。

うまくいったでしょ。

ちなみにコンパイルするとパラメータの設定が初期化されてしまいます。

気になる人は、上の方の

#property indicator_color1 Red

#property indicator_color2 Blue

#property indicator_color3 Green

#property indicator_color4 Yellow

extern int Param1=0;

の値を変えてみてくださいね。

FXや株でも何でもそうですが、過去のデータを参考に投資を行うと思います。

自分なりに、相場がこうなるといい感じになりそうだから買おう、とかルールを決めている人が多いと思います。

というか、ルールを決めないとほとんどギャンブルになっちゃうので、決めましょうね。

で、このルールを見つけるのが大変ですよね。

私も日々、見つけようと努力しています。

グラフなどをみて、この線を組み合わせるといいかもしれない！

と思ったら、過去にどうなっているか調べるわけです。

ここからが、プログラムを組める人と組めない人の差が開きます。

組めない人は、グラフとにらめっこして、ここでは増えた、ここではダメ。

とかすべて、見ていかなければなりません。

その上、パラメータをいじってみたら、もう一度同じことを繰り返す必要があります。

大変ですよね。

たぶん、ルールを見つける作業がいやになるのは、この辺ではないかと。。。

逆にプログラムを組める人は、最初にルールを元にしたプログラムを組みます。

後は、解析結果を待つだけです。

バックテストで、パラメータを変えながら最適な結果を見つける方法も説明しました。

１度組んでしまえば、解析まで自動でできます。

まあ、プログラムを組むのが面倒なんですがね。

プログラムを組める場合と組めない場合では、どちらが有利か説明するまでも無いと思います。

いままで、いろいろなサンプルで説明してきましたが、難しいと思う人も多いかと思います。

でも、行数を見てください。

１００行ぐらいで、できているはずです。

たった１００行ですよ。

これで、それなりのものができてしまうんです。

少し頑張ればできそうな気がしませんか？

メタトレーダーのプログラムは、ウィンドウズのプログラムを書こうと思うより、はるかに楽です。

よく考えてください。

やることは、値の比較だけ。

やっても何か特殊な計算をするぐらいですよね。

たくさんの指標を計算する関数がMT4には用意されているので、オリジナルで作ることは少ないと思います。

だから、指標の組み合わせと比較だけです。

全く目的が違うんです。

だから複雑なことをやらせないので、短いステップ数で完成することが多いんです。

いくつか、自分で組んでみると分かると思います。

まずは、まねから始めてみませんか？

覚えることは、

1. 変数の宣言
2. if文
3. for文
4. 標準で用意されている関数の呼び方

この４つをマスターすれば、あらかた組めますのでチャレンジしてみましょう。

４の標準で用意されている関数は、基本的に覚える必要はありません。

使いたいときに探して、目的のものがあれば使う。

無ければ計算で求めるだけです。

単純に考えましょう。

では、頑張ってください。

まだまだ、記事数も多くない「めたぷろ」ですが、せっかくプログラムを説明していてもダウンロードできるファイルがどこにあるか分かりにくくなってきました。

ということで、「MT4　めたぷろ　ダウンロードセンター」を開設しました。

めたぷろで、紹介したコードやサンプルファイルをダウンロードするためのサイトです。

記事がない分、探しやすくなると思います。

ちょこっと作ってみたインジケータやEAがあるので、めたぷろで紹介しないものも順次公開予定です。

たまにのぞいてみてください。

前回、EAを作ってみるでつくったEA（自動売買）、MA_EAをバックテストしてみました。

結果は、あまりよくありませんでしたね。

でも、EAを作ったときにパラメータをいくつか外出しにしたと思います。

覚えていますか？

もしかしたら、このパラメータをいじるといい感じの結果が出そうな予感がしませんか？

思わなくてもしたことにしてください。

話が進まないので。。。

で、パラメータのパターンをテストしていけばいいだけです。

たとえば、１つのパラメータで５パターンするとします。

１つで５パターン。

　　楽勝！！

２つで２５パターン。

　　ちょっといやになってきますね。

３つで、１２５パターン。

　　やる気でないですね。

４つで、６２５パターン。

　　もう無理です。

やっぱり無理でした。。。

っていうことになりそうですが、メタトレーダーには、便利な機能があります。

スタート、ステップ、ストップの値をパターン分析したいパラメータにセットすると、すべての組み合わせを行ってくれる機能があるんです。

テスターに「Optimization」というチェックがあったのに気がつきませんでしたか？

このチェックが、パターン分析を行うチェックなんです。

では、チェックを入れてスタート！

と行く前に、

先ほどの説明のスタート、ステップ、ストップを設定して、どのパラメータを変更して解析させるかを指定する必要があります。

では、「Expert properties」ボタンを押して、プロパティウィンドウを開いてください。

次に、「パラメータの入力」タブを押してください。

では、設定していきます。

BuyLots：変更しません。

LossEntry：変更しません。

残りは、すべてチェックします。

MaPerirod：スタート（７）、ステップ（７）、ストップ（３５）

TakeMa：スタート（５）、ステップ（５）、ストップ（２５）

今回は、EA（自動売買）のプログラムを作ってみたいと思います。 今回は、単純移動平均のラインをブレイクしたときに順張りするＥＡを作成します。  

単純移動平均をブレイクしたときに、成行でオーダーし、テイク（利益確定）ポイントとロスカットポイントを指定します。

これは、通信できなかったときの保険で、実際の利益確定やロスカットはＥＡが値を確認して行います。  

注意事項ですが、ここで作成したプログラムを実運用で利用してもかまいませんが、利益を保証するものではありません。

ご自分の判断で、利用してください。

損害等は、一切保証しません。

では、プログラムの作成を行いましょう。  

ＭｅｔａＥｄｉｔｏｒを開き、Expert Advisor Wizardを開きます。  

Expert Advisor作成

Expert Advisorを選択し、次へを押します。

EAの名前を決める

NAMEに「MA_EA」と入力します。

パラメータを指定できますが、今回はコード上で指定しますので、そのまま完了を押してください。

スケルトンが作成されます。

前半の設定を行います。

//オーダーするときのロット数をパラメータとして指定します。

//0.1ロットが1万通貨となります。

extern double BuyLots=0.1;

//単純移動平均のサンプリングする足の数をパラメータとして指定します。

extern int MAPeriod=21;

//EAが利益確定するポイント数をパラメータとして指定します。

extern int TakeMA=20;

//EAがロスカットするポイント数をパラメータとして指定します。

extern int LossMA=10;

//オーダー時に保険として設定する利益確定ポイントを指定します。

extern int TakeEntry=25;

//オーダー時に保険として設定するロスカットポイントを指定します。

extern int LossEntry=25;

//オーダー番号を格納する変数を設定します。

int ticket=0;

//このEAのオーダーを判断するための番号を設定します。

int MagicNo=1;

今回は、初期処理と終了処理ではなにも行いません。

実行処理を指定します。

int start()

  {

//ポジションを持っているか判断するフラグを設定します。

//0がポジションなし、1がポジションを持っていることにします。

    int KeepPosition=0;

//現在持っているオーダー数を取得します。

    int total=OrdersTotal();

    int i;

//現在持っているオーダーの中からこのEAがポジションを持ったオーダーを探します。

    for(i=0;i < total;i++){

//オーダーを選択します。

        if(OrderSelect(i, SELECT_BY_POS)==true)

        {

//オーダーの通貨ペアが同じで、このEAが指定したマジックNoが同じものを探します。

            if(Symbol() == OrderSymbol() && OrderMagicNumber() == MagicNo)

            {

//このEAがオーダーしたものが見つかったときはオーダーを持っていることにします。

                KeepPosition = 1;

//チケット番号をセットします。

                ticket=OrderTicket();

//ループを抜けます。

                break;

            }

        }

    }

//現在から過去の単純移動平均を5本分取得します。

    double Ma0=iMA(NULL,0,MAPeriod,0,MODE_SMA,PRICE_CLOSE,0);

    double Ma1=iMA(NULL,0,MAPeriod,0,MODE_SMA,PRICE_CLOSE,1);

    double Ma2=iMA(NULL,0,MAPeriod,0,MODE_SMA,PRICE_CLOSE,2);

    double Ma3=iMA(NULL,0,MAPeriod,0,MODE_SMA,PRICE_CLOSE,3);

    double Ma4=iMA(NULL,0,MAPeriod,0,MODE_SMA,PRICE_CLOSE,4);

//ポジションを持っている場合、クローズするか確認します。

    if(KeepPosition == 1)

    {

//オーダーから何本足を描画したかを求めます。

//オーダーから最小値、最大値を求めるために利用します。

        int ChkAshi = (OrderOpenTime()-TimeCurrent())/(Period()*60);

//売りポジションの場合

        if(OrderType() == OP_SELL)

        {

//オーダーしてから、TakeMAの2倍の値を出して、TakeMAまで戻ってきたときにクローズします。

//利益確定は、戻ってきたときとオーダー時に設定したポイントの2つが利益確定ポイントです。

            if(OrderOpenPrice()-TakeMA*Point >= Ask && OrderOpenPrice()-TakeMA*2*Point >= Low[iLowest(NULL,0,MODE_LOW,0,ChkAshi)])

            {

                OrderClose(OrderTicket(),OrderLots(),Ask,3,Green);

            }

//LossMAで指定したポイントを割ってしまったときにロスカットします。

            if(OrderOpenPrice()+LossMA*Point <= Ask)

            {

                OrderClose(OrderTicket(),OrderLots(),Ask,3,Green);

            }

        }

//買いポジションの場合

//売りポジションと同じことを行います。

//符号の向きが逆なのとAskではなくBidを利用しているところが違います。

        else if(OrderType() == OP_BUY)

        {

            if(OrderOpenPrice()+TakeMA*Point <= Bid && OrderOpenPrice()+TakeMA*2*Point <= High[iHighest(NULL,0,MODE_HIGH,0,ChkAshi)])

            {

                OrderClose(OrderTicket(),OrderLots(),Bid,3,Green);

            }

            if(OrderOpenPrice()-LossMA*Point >= Bid)

            {

                OrderClose(OrderTicket(),OrderLots(),Bid,3,Green);

            }

        }

    }

//ポジションを持っていない場合、ポジションを持つかどうか確認します。

    else if(KeepPosition == 0)

    {

//下降トレンドの場合

        if(Ma4 > Ma3 && Ma3 > Ma2 && Ma2 > Ma1 && Ma1 > Ma0)

        {

//Ma4、Ma3、Ma2のクローズが大きくて、Ma1と現在値（Bid）が小さい場合売りポジションを持ちます。

            if(Ma4 < Close[4] && Ma3 < Close[3] && Ma2 < Close[2] && Ma1 > Close[1] && Ma0 > Bid)

            {

                ticket=OrderSend(Symbol(),OP_SELL,BuyLots,Bid,3,Bid+LossEntry*Point,Bid-TakeEntry*Point,”MA_EA Sell”,MagicNo,0,Blue);

                if(ticket==0) Print(”Error opening SellChk order : “,GetLastError());

            }

        }

//上昇トレンドの場合

        else if(Ma4 < Ma3 && Ma3 < Ma2 && Ma2 < Ma1 && Ma1 < Ma0)

        {

//Ma4、Ma3、Ma2のクローズが小さくて、Ma1と現在値（Bid）が小さい場合買いポジションを持ちます。

            if(Ma4 > Close[4] && Ma3 > Close[3] && Ma2 > Close[2] && Ma1 < Close[1] && Ma0 < Ask)

            {

                ticket=OrderSend(Symbol(),OP_BUY,BuyLots,Ask,3,Ask-LossEntry*Point,Ask+TakeEntry*Point,”MA_EA Buy”,MagicNo,0,Red);

                if(ticket==0) Print(”Error opening BuyChk order : “,GetLastError());

            }

        } 

    }

   return(0);

  }

OrderSelectで、選択しているオーダーはOrder???関数で値を取得することができます。

Low[iLowest(NULL,0,MODE_LOW,0,ChkAshi)、High[iHighest(NULL,0,MODE_HIGH,0,ChkAshi)]は、オーダーしてからの最安値、最高値を求めています。

OrderSendは売買注文を行う関数で、成行、IFD、OCOなどのオーダーを組み合わせて注文することができます。

今回の例では、成行＋OCO注文を行っています。

また、ticketが0の場合は注文失敗で、GetLastErrorを利用してエラー番号を取得しています。

Printは、操作履歴に結果を出力する関数です。

操作を残したいときに利用すると便利です。

さて、前回と前々回で、トレンドラインを書くプログラムの基本とプログラムを書くときに気をつけたほうがいいことを書きました。

今回は、トレンドラインの総仕上げとして、ループ回数を最小にして、好きな本数のトレンドラインを書くインジケータを作成します。

少々、難易度が上がりますが、がんばってついてきてください。

トレンドラインを書いてみるを参考にインジケータのスケルトンを作成してください。

前回のソースにそのまま上書きでもかまいません。

まず、前半の定義部分です。

#property indicator_chart_window
extern int nPeriod=9;
extern int Limit=350;
extern int nLine=3;

nLineを追加しました。

これは、トレンドラインの数です。

デフォルトでは、３本ずつ書きます。

初期化部分です。

int init()
{
    int i;
    for(i=0;i<nLine;i++)
    {
        ObjectCreate(”Trend DN-”+i,OBJ_TREND,0,0,0,0,0);
        ObjectSet(”Trend DN-”+i,OBJPROP_COLOR,Maroon);
        ObjectSet(”Trend DN-”+i,OBJPROP_WIDTH,3);

        ObjectCreate(”Trend UP-”+i,OBJ_TREND,0,0,0,0,0);
        ObjectSet(”Trend UP-”+i,OBJPROP_COLOR,Green);
        ObjectSet(”Trend UP-”+i,OBJPROP_WIDTH,3);
    }

   return(0);
}

オブジェクトの作成ですが、前回と違って指定した数だけ作る必要があるため、ループをまわして指定した数のトレンドラインを書くためのオブジェクトを作成します。

名前が、「Trend UP-0″」など固定でしたが、数にあわせて名前を変更したいので、「Trend UP-”+i」としてループの値を名前に追加するように変更しました。

また、線が細くて見にくかったので、今回は少し太く描画させて見ます。

ObjectSet(”Trend DN-”+i,OBJPROP_WIDTH,3);

の部分で、線の幅をデフォルトの1ポイントから3ポイントに広げます。

次は、終了処理です。

int deinit()
{
    int i;
    for(i=0;i<nLine;i++)
    {
        ObjectDelete(”Trend UP-”+i);
        ObjectDelete(”Trend DN-”+i);
    }
   return(0);
}

初期処理と同じく、指定された数分だけ削除するようにループしています。

次は、本題のメイン処理です。

int start()
{

//今回は、線の数が分からないので、配列を使います。
//まず、空の配列を用意します。
//固定で指定する場合は、double r[10];の様に数字を指定します。
    double r[];
    int rt[];
    double s[];
    int st[];

//配列に必要な入れ物を指定した数だけ用意します。
//はじめと終わりの入れ物が必要なので、実際の線の数より1つ多い数を指定します。
    ArrayResize(r,nLine+1);
    ArrayResize(rt,nLine+1);
    ArrayResize(s,nLine+1);
    ArrayResize(st,nLine+1);

    int nCurBar;
    int ChkRLine=0;
    int ChkSLine=0;

    if(Bars<Limit) Limit=Bars-nPeriod;

//前回とは逆に最新のものから指定本数までループをまわします。
    for(nCurBar=0; nCurBar<Limit; nCurBar++)
    {

//一番低い谷を見つけます。
        if(Low[nCurBar+(nPeriod-1)/2] == Low[iLowest(NULL,0,MODE_LOW,nPeriod,nCurBar)])
        {
//値が1つだけでは線を引けないので、配列に代入だけします。
            if(ChkSLine==0)
            {
                s[ChkSLine]=Low[nCurBar+(nPeriod-1)/2];
                st[ChkSLine]=nCurBar+(nPeriod-1)/2;
                ChkSLine++;
            }
//2本目の値で、1つ目の値より小さい場合描画します。
            else if(s[ChkSLine-1] < Low[nCurBar+(nPeriod-1)/2] && ChkSLine <= nLine)
            {
//値の代入を行い
                s[ChkSLine]=Low[nCurBar+(nPeriod-1)/2];
                st[ChkSLine]=nCurBar+(nPeriod-1)/2;
//描画させます。
                ObjectMove(”Trend DN-”+(ChkSLine-1),1,Time[st[ChkSLine-1]],s[ChkSLine-1]);
                ObjectMove(”Trend DN-”+(ChkSLine-1),0,Time[st[ChkSLine]],s[ChkSLine]);
//ラインを1つ進めます。
                ChkSLine++;
            }
//もし、1つ前より小さい値が見つかったときに値を入れ替えます。
            else if(s[ChkSLine-1] > Low[nCurBar+(nPeriod-1)/2] && ChkSLine <= nLine)
            {
                s[ChkSLine-1]=Low[nCurBar+(nPeriod-1)/2];
                st[ChkSLine-1]=nCurBar+(nPeriod-1)/2;
            }
        }

//谷と同様に山を見つけます。
        if(High[nCurBar+(nPeriod-1)/2] == High[iHighest(NULL,0,MODE_HIGH,nPeriod,nCurBar)])
        {
            if(ChkRLine==0)
            {
                r[ChkRLine]=High[nCurBar+(nPeriod-1)/2];
                rt[ChkRLine]=nCurBar+(nPeriod-1)/2;
                ChkRLine++;
            }
            else if(r[ChkRLine-1] > High[nCurBar+(nPeriod-1)/2] && ChkRLine <= nLine)
            {
                r[ChkRLine]=High[nCurBar+(nPeriod-1)/2];
                rt[ChkRLine]=nCurBar+(nPeriod-1)/2;
                ObjectMove(”Trend UP-”+(ChkRLine-1),1,Time[rt[ChkRLine-1]],r[ChkRLine-1]);
                ObjectMove(”Trend UP-”+(ChkRLine-1),0,Time[rt[ChkRLine]],r[ChkRLine]);
                ChkRLine++;
            }
            else if(r[ChkRLine-1] < High[nCurBar+(nPeriod-1)/2] && ChkRLine <= nLine)
            {
                r[ChkRLine-1]=High[nCurBar+(nPeriod-1)/2];
                rt[ChkRLine-1]=nCurBar+(nPeriod-1)/2;
            }
        }

//上昇・下降ともに指定本数見つかった場合、ループを抜けます。
        if(ChkSLine > nLine && ChkRLine > nLine)break;
    }

   return(0);
}

メイン処理は、ループの中に納まっていて、必要な本数が見つかった後、breakで抜けいていることが分かると思います。

必要な数だけ、ループをまわすようにして負荷を抑えています。

値は、配列に格納しています。

本当は、配列に代入しなくても描画だけなら可能です。

ですが、今後の拡張のために値を残しておくようにしました。

値を残しておくことで、いろいろ拡張できると思います。

値の格納も1つ目の変数への格納と、条件を満たした場合に次の配列へ格納すること、一度格納した配列より大きい・小さい値の場合入れ替える処理を追加してあります。

少々複雑になりましたが、コンパクトにまとまっていると思います。

インジケータは、

インストールパス\MetaTrader\experts\indicators

に入れてください。

前回紹介した、トレンドラインを書いてみるはご覧になりましたか？

MT４でも手動で書くことができますが、やっぱり自動が楽ですよね。

でも、ちゃんと動くと思いますが、実はあまりいいプログラムではありません。

ちゃんと動く＝いいプログラム

ではないということです。

では、何が悪いか。。。

ソースを見た時点で、だめだめジャン！！

って思った人は、プロかセミプロレベルの人ですね。

では、どこがダメなんでしょうか？

まず、for文でループを回している部分がありますよね。

ここが、ダメです。

for文じゃなくて、while文を使うってわけじゃありません。

基本的にループをまわすには、どちらを使ってもかまいません。

使いやすい方を使ってください。

では、ダメな部分。

調査する足の最大数からカウントダウンしてますよね。

古い方から新しい方へ調査しています。

別に古い方から新しい方へループをまわすことが悪いんじゃないんですが、今回はダメです。

実際に動かすと、トレンドラインを引く山や谷を見つけるのに、新しい方から数十本の足ですんでいますよね。

ということは、無駄なループをたくさん回しているということになります。

ループは、結構PCに負担なんです。

為替は、生き物ですから１秒でも無駄にしたくありませんよね。

だから、無駄を省く必要があります。

ですから、正解は新しい方から古い方にループを回して、必要な山や谷を見つけたらループを抜けるように組めばいいんです。

「break」という命令で、ループを抜けることができます。

もう一つあります。

ループの中で余分な変数に代入して、ループを抜けた後に上昇・下降か判断している部分があります。

ループ内で、判断すれば無駄が省けますよね。

プログラムは、動くことも大事ですがこうした無駄を省くように心がけると結果的に高速に動いたり、見やすいソースになります。

ぜひ、自分で組むときは心がけてください。

次は、もう一度トレンドラインを引くインジケーターを作ります。

上記で説明した、ダメな部分の修正ともう一つ。

表示してみると分かりますが、最新の１本だけだとトレードに使えません。

少なくても３本ぐらいないと、トレードの参考にならないはずです。

ですから、１本のトレンドラインから３本に増やします。

次回をお楽しみに！

前回は、インジケーターを作ってみるで足に対応したバッファに代入することで、メタトレーダーの機能を使いグラフを自動的に描画方法を試してみました。

今回は、オブジェクトという機能を使い好きな場所に線や文字などを描画する方法を試してみます。

で、単純に線を書いてもおもしろくないのでトレンドラインを書いてみたいと思います。

トレンドとは、上下に動きながら移動している為替も平均してみると上昇していたり、下降しているときがあります。

こうした状態をトレンド相場と呼びます。

平均した線が横ばいの場合は、レンジ相場と呼びます。

為替は、上昇トレンド、下降トレンド、レンジ相場の３種類のどれかの状態になっています。

このトレンドを表す線をトレンドラインと呼びます。

上昇トレンドラインは、上下に動いている山の高値と高値を結んだ線。

下降トレンドラインは、谷の安値と安値を結んだ線のことをいいます。

このトレンドラインをインジケーターの機能を使って、描画したいと思います。

インジケーターを作ってみるを参考にスケルトンを作ります。

Nameを「TrendLine」。

その他は、何も入力しません。

まずは、TrendLineのスケルトンを作成してください。

まず、前半の宣言部分を作成します。

//メインウィンドウに描画します。

#property indicator_chart_window

//山と谷を見つける幅をパラメータとして指定します。

extern int nPeriod=9;

//先頭から何本まで山、谷を見つけるかパラメータとして指定します。

extern int Limit=350;

次は、初期化処理です。

int init()

{

//下降トレンドライン０番目のオブジェクトを作ります。

    ObjectCreate(”Trend DN-0″,OBJ_TREND,0,0,0,0,0);

//下降トレンドライン０番目のオブジェクトの色を指定します。

    ObjectSet(”Trend DN-0″,OBJPROP_COLOR,Maroon);

//上昇トレンド０番目のラインオブジェクトを作成します。

    ObjectCreate(”Trend UP-0″,OBJ_TREND,0,0,0,0,0);

    ObjectSet(”Trend UP-0″,OBJPROP_COLOR,Green);

   return(0);

}

上昇、下降用のトレンドラインを引くためのオブジェクトを用意しました。

次は、終了処理です。

インジケータを削除したときに、オブジェクトが残ってしまいます。

そのために、インジケータ終了時に自分が作ったオブジェクトを削除する処理を追加します。

次は、トレンドラインを描画するための山、谷を見つけラインを引く処理です。

これで、終了です。

コンパイルして、インジケータを表示させてみてください。

以下のようにトレンドラインが表示されれば成功です。

TrendLineインジケーター

ちょっとは、らしいものができたのではないでしょうか？

少しずつレベルをアップしていきますね。

今回のプログラムは、以下からダウンロードできます。

ここから、ダウンロード

インジケータは、

インストールパス\MetaTrader\experts\indicators

に入れてください。

→この記事の続きを読む

今回は、インジケータを作ってみようと思います。 3本の移動平均を表示したいと思います。  

 簡単なプログラムを作ってみるを参考にMetaEditorのメニューでFile-Newで「Expert Advisor Wizard」を開きます。 「Custom Indicator」にチェックを入れて、次へを押します。   

3EAパラメータ追加

Nameに３EA（名前なので何でもいいです）、Addボタンを押してパラメータを３つ追加します。

Nameをそれぞれ、Peried1、Peried2、Peried3とします。 Typeはintにしてください。  

次へを押します。

グラフの種類を選択

Addボタンを押して、表示するグラフのラインを追加します。

３つ追加して、Red、Yellow、Greenを選んでください。

別に違う色でもかまいません。

今回は、線で表示するのでTypeはLineのままにしてください。

完了を押すと、スケルトンが作成されます。

先頭の方に以下の行があると思います。

コメントを付けて、説明します。

//メインウィンドウに表示する。

#property indicator_chart_window

//グラフに利用する入れ物が３つ（最大８個）

#property indicator_buffers 3

//１本目は、太さ１の赤

#property indicator_color1 Red

//２本目は、太さ１の黄色

#property indicator_color2 Yellow

//３本目は、太さ１の緑

#property indicator_color3 Green

//入力するパラメータは、以下の3つ

extern int       Peried1;

extern int       Peried2;

extern int       Peried3;

//表示するグラフに対応する入れ物３つ

double ExtMapBuffer1[];

double ExtMapBuffer2[];

double ExtMapBuffer3[];

extern int       Peried1=7;

extern int       Peried2=14;

extern int       Peried3=21;

とデフォルトの数字を設定しましょう。

これで、何も入力しなくても利用可能になります。

次は、初期設定です。

int init()

  {

//—- indicators

//１本目（０番から始まる）はライン

   SetIndexStyle(0,DRAW_LINE);

//１本目のバッファをExtMapBuffer1とする

   SetIndexBuffer(0,ExtMapBuffer1);

//２本目はライン

   SetIndexStyle(1,DRAW_LINE);

//２本目のバッファをExtMapBuffer2

   SetIndexBuffer(1,ExtMapBuffer2);

//３本目はライン

   SetIndexStyle(2,DRAW_LINE);

//３本目のバッファをExtMapBuffer3

   SetIndexBuffer(2,ExtMapBuffer3);

//—-

   return(0);

  }

最初の方で、色を設定したのでここでは、どのように描画するか。

線ごとにバッファをどれにするかをしていします。

これで、ExtMapBuffer1などに値を入れるだけで線を書いてくれるようになります。

ExtMapBuffer1などは、描画されている足の数に対応したバッファです。

ExtMapBuffer1[0]から始まり、最新が0になります。

 

実際に、移動平均の値を登録していきましょう。

int start()

  {

//変化していない足の数を取得する

   int counted_bars=IndicatorCounted();

//値を入れる足番号の変数

   int i;

//表示されている足の数から、変化のない足の数を引いたもの（描画すべき足）の値をセット

   i = Bars-counted_bars-1;

//最新の足（0）をを描画するまで繰り返す。

//古いものから書いていきます。

   while(i>=0)

   {

//１本目の単純移動平均の値を取得

       ExtMapBuffer1[i]=iMA(NULL,0,Peried1,0,MODE_SMA,PRICE_CLOSE,i);

//２本目の単純移動平均の値を取得

       ExtMapBuffer2[i]=iMA(NULL,0,Peried2,0,MODE_SMA,PRICE_CLOSE,i);

//３本目の単純移動平均の値を取得

       ExtMapBuffer3[i]=iMA(NULL,0,Peried3,0,MODE_SMA,PRICE_CLOSE,i);

//１つ新しい足番号にする（1引く）

       i–;

   }

   return(0);

  }

 

さて、以上でプログラムは終了です。

コンパイル（F5）してみましょう。

メタトレーダーへ戻って、3EAを表示させたい通貨のウィンドウへドロップしてみてください。

 

3EAパラメータ

ドラッグしたときに表示されるウィンドウの「パラメータ入力」タブを押すと上の画面のようになります。

初期設定した内容が表示されていることが分かると思います。

この設定は、後で変更可能です。

OKボタンを押して、描画させてみましょう。

3EA表示

3種類の移動平均が表示されていることが分かります。

簡単でしょ！！

 

iMaが移動平均を取得する関数です。

パラメータで、いろいろな移動平均を取得できます。

今回は、単純移動平均（MODE_SMA）、終値（PRICE_CLOSE）を利用しました。

他にも、指数平均、平滑平均、加重平均なども選べます。

終値の他にも始値、高値、安値、平均をとったものなどを選ぶことができます。

 

今回のプログラムは、以下からダウンロードできます。

ここから、ダウンロード

 

インジケータは、

インストールパス\MetaTrader\experts\indicators

に入れてください。